// Persistence of Vision Ray Tracer Scene Description File
// File: tapeta_kulki.pov
// Vers: 3.5
// Desc: Tapeta z fotonowymi kulkami
// Date: 04/08/05
// Auth: Adam Druzd
//

#version 3.5;
#include "colors.inc"
#declare Photons=on;

global_settings {
  //assumed_gamma 1.0
  max_trace_level 15
  #if (Photons)          // global photon block
    photons {
      spacing 0.02                 // specify the density of photons
    }

  #end
}

// ----------------------------------------

camera {
  location  <0,10,-15>
  look_at   <.5,.5,0>
  //location  <1,10,.5>
  //look_at   <1,0,.5>
  angle 32
}

light_source {
  <-500,300,250>       // light's position
  color rgb <1,1,1>       // light's color
  photons {           // photon block for a light source
    refraction on
    reflection on
  }
}

sky_sphere {
  pigment {
    gradient y
    color_map {
      [0.0 rgb <0.6,0.7,1.0>]
      [0.7 rgb <0.0,0.1,0.8>]
    }
  }
}


plane {
  y, 0
  texture {
    pigment { color Gray }
  }
}


#declare M_Glass=    // Glass material
material {
  texture {
    pigment {rgbt 1}
    finish {
      ambient 0.0
      diffuse 0.05
      specular 0.6
      roughness 0.005
      reflection {
        0.1, 1.0
        fresnel on
      }
      conserve_energy
    }
  }
  interior {
    ior 1.5
    fade_power 1001
    fade_distance 0.9
    fade_color <0.5,0.8,0.6>
  }
}


#declare r=.7;
#declare a=2*r;

#declare k1=sphere
{
  <0,0,0>,r
  material { M_Glass }

  photons { 
    target 1.0
    refraction on
    reflection on
  }
}

object { k1 translate <0,r,0> }
object { k1 translate <a,r,0> }
object { k1 translate <r,r,a*sqrt(3)/2> }
object { k1 translate <r, r+a*sqrt(2/3), a*sqrt(3)/6> }